Zeus IDE

Posted: **Sun Jan 02, 2005 3:54 pm**

Hello Jussi,

are you planning to incorporate support for MS Help 2.0 Files in the QuickHelp Function?

Visual Studio .NET 2002 and above ship it's Help Files in this format, so i am forced to use the dated old Files vom VC6 (CHM Format) - which are sometimes out of date

Bye, Egon

Posted: **Sun Jan 02, 2005 8:27 pm**

Hi Egon,

Unfortunately it appears Microsoft will never be making public the MS Help 2.0 file format and this makes it very difficult to add this help file format to the Quick Help feature

But it is possible to access the MS Help 2.0 engine using COM and at least for me the following Zeus macro does do a simplified version of the Zeus Quick Help search for MS Help 2.0 files:

Code: Select all

'        Name: MSDN Macro
'
'      Author: Jussi Jumppanen
'
'    Language: VB Script Macro
'
' Description: This VB Script creates a Document Explorer object
'              to search the MSDN for the current word.
'
'  How To Run: All Zeus macros can be run using the macro execute menu
'              item or they can be bound to the keyboard or they can
'              be attached to the macro drop down or popup menus.
'

Dim oMSDN

Function key_macro()
  On Error Resume Next

  ' create the Document Explorer object
  Set oMSDN = CreateObject("DExplore.AppObj.7")

  If Err.Number = 0 Then
    ' this macro only works for documents
    is_document = zeus.is_document()

    If is_document = 1 Then
      ' get the current word or the marked text
      word = zeus.macro_tag("$WEX")

      ' make sure we have a word
      If Len(word) > 0 Then

        ' set the MSDN collection
        oMSDN.SetCollection "ms-help://MS.VSCC", ""

        ' display the index panel
        oMSDN.Index

        ' search for the current word
        oMSDN.DisplayTopicFromKeyword word

      Else
        ' give some feedback to the user
        zeus.message "Place the cursor on word or mark some text."
      End If

    Else
      ' give some feedback to the user
      zeus.message "This script requires an opne document or output window."
    End If

  Else
    ' Document Explorer not supported
    error_message = "The .NET Framework Document Explorer does not appear to be installed on this machine."

    ' display error message in the status bar
    zeus.message error_message

    MsgBox error_message
  End If

End Function

key_macro() 'run the macro

Cheers Jussi

Posted: **Mon Jan 03, 2005 5:53 am**

Hi Jussi,

thank you for the Script you've attached i will try it this evening

Bye, Egon

Zeus IDE

MS Help 2.0 Support

MS Help 2.0 Support